#################################################
#
#  (C) 2019 Slávek Banko
#  slavek.banko (AT) axis.cz
#
#  Improvements and feedback are welcome
#
#  This file is released under GPL >= 2
#
#################################################

cmake_minimum_required( VERSION 3.5 )


##### include our cmake modules #################

include( TDEL10n )


##### prepare strings from data files ###########

## style names
file( GLOB_RECURSE _style_files
      RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}
      ${CMAKE_CURRENT_SOURCE_DIR}/data/styles/*.xml )
unset( _styles_l10n )
foreach( _style_file ${_style_files} )
    get_filename_component( _style_name "${_style_file}" NAME_WE )
    string( REPLACE "_" " " _style_name "${_style_name}" )
    set( _styles_l10n "${_styles_l10n}i18n(\"${_style_name}\");\n" )
endforeach( )
file( WRITE "${CMAKE_CURRENT_SOURCE_DIR}/data/styles/.tde_l10n" "${_styles_l10n}" )

## font attributes
set( _fonts_attribs "data/fonts/mappings/*.xml" )
foreach( _fonts_attrib
    "rosegarden-font-encoding,name"
    "font-information,origin"
    "font-information,copyright"
    "font-information,mapped-by"
    "font-information,type" )

    set( _fonts_attribs "${_fonts_attribs}:${_fonts_attrib}" )
endforeach( )


##### create translation templates ##############

tde_l10n_create_template(
    CATALOG "messages/rosegarden"
    SOURCES
        "src"
        "doc/en/tips"
        "data/styles/.tde_l10n"
    ATTRIBUTES
        ${_fonts_attribs}
)

tde_l10n_create_template(
    CATALOG "desktop_files/rosegarden-desktops"
    SOURCES data/desktop/*.desktop
)
