#################################################
#
#  (C) 2014 Slávek Banko
#  slavek (DOT) banko (AT) axis.cz
#
#  Improvements and feedback are welcome
#
#  This file is released under GPL >= 2
#
#################################################


##### set project version ########################

include( TDEVersion )
cmake_minimum_required( VERSION ${TDE_CMAKE_MINIMUM_VERSION} )
tde_set_project_version( )


##### general package setup #####################

project( libr )
set( PACKAGE libr )
set( PACKAGE_VERSION 0.7.0 )


##### include essential cmake modules ###########

include( FindPkgConfig )
include( FindThreads )
include( CheckCSourceCompiles )
include( CheckIncludeFile )
include( CheckFunctionExists )
include( CheckLibraryExists )
include( CheckSymbolExists )


##### include our cmake modules #################

include( TDEMacros )


##### setup install paths #######################

include( TDESetupPaths )
tde_setup_paths( )


##### optional stuff ############################

option( WITH_GCC_VISIBILITY   "Enable fvisibility and fvisibility-inlines-hidden" ON )
option( WITH_BACKEND_LIBBFD   "Build with libbfd backend"    ON  )
option( WITH_BACKEND_LIBELF   "Build with libelf backend"    OFF )
option( WITH_BACKEND_READONLY "Build with read-only backend" OFF )
option( WITH_GTK              "Build support for GTK"        OFF )

# NOTE: WITH_GTK build gtk bindings to ease libr in gtk applications.
#       It uses weak linkage, so gtk will be required during build
#       only and not strictly necessary during runtime.


#### configure checks ###########################

include( ConfigureChecks.cmake )


#### pkg-config #################################

set( prefix      ${CMAKE_INSTALL_PREFIX} )
set( exec_prefix ${EXEC_INSTALL_PREFIX} )
set( libdir      ${LIB_INSTALL_DIR} )
set( includedir  ${INCLUDE_INSTALL_DIR}/libr )

configure_file( libr.pc.in libr.pc @ONLY )
install( FILES ${CMAKE_CURRENT_BINARY_DIR}/libr.pc
         DESTINATION ${PKGCONFIG_INSTALL_DIR} )


##### build #####################################

tde_auto_add_subdirectories()


##### write configure files #####################

configure_file( src/config.h.cmake config.h @ONLY )
configure_file( doc/libr.cfg.cmake doc/libr.cfg @ONLY )