#################################################
#
#  (C) 2019 Slávek Banko
#  slavek.banko (AT) axis.cz
#
#  Improvements and feedback are welcome
#
#  This file is released under GPL >= 2
#
#################################################

cmake_minimum_required( VERSION 2.8 )


##### include our cmake modules #################

set( CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules" )
include( TDEL10n )


##### force to use standard xgettext ############

set( __bak_KDE_XGETTEXT_EXECUTABLE ${KDE_XGETTEXT_EXECUTABLE} )
set( KDE_XGETTEXT_EXECUTABLE "${XGETTEXT_EXECUTABLE}" )


##### create translation templates ##############

tde_l10n_create_template(
    CATALOG "kvirc"
    SOURCES
        "src"
        "data/defscript/*.kvs"
    KEYWORDS
        - i18n:1c,2
        __tr __tr_no_lookup __tr2qs __tr2wc __tr2ws tr
    X-POT -
    DESTINATION "po/kvirc"
)

file( GLOB _modules
      RELATIVE ${CMAKE_CURRENT_SOURCE_DIR}/po/modules
      "${CMAKE_CURRENT_SOURCE_DIR}/po/modules/*"
)
foreach( _module ${_modules} )
    if( IS_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/po/modules/${_module} AND
        IS_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/src/modules/${_module} )

        tde_l10n_create_template(
            CATALOG "${_module}"
            SOURCES
                "src/modules/${_module}"
            KEYWORDS
                - i18n:1c,2
                __tr_ctx __tr_no_lookup_ctx __tr_no_lookup
                __tr2qs_ctx __tr2wc_ctx __tr2ws_ctx __tr2qs_no_lookup
            X-POT -
            DESTINATION "po/modules/${_module}"
        )
    endif( )
endforeach( )


##### restore kde-xgettext ######################

set( KDE_XGETTEXT_EXECUTABLE "${__bak_KDE_XGETTEXT_EXECUTABLE}" )
unset( __bak_KDE_XGETTEXT_EXECUTABLE )
