AC_ARG_VAR(PKGCONFIGFOUND, [Path to pkg-config])
AC_CHECK_PROG(PKGCONFIGFOUND, pkg-config,[yes])

#------------------------------------------------------------------
# Check for Exiv2 library
#------------------------------------------------------------------

have_exiv2='no'
if test "$PKGCONFIGFOUND" = "yes" ; then
 KDE_PKG_CHECK_MODULES(EXIV2, exiv2 >= 0.12, have_exiv2=yes,have_exiv2=no)
else
 AC_MSG_WARN([pkg-config not found. You have to install pkg-config first. libkexiv2 depends on it.])
fi

if test "x$have_exiv2" != "xyes"; then
  AC_MSG_WARN([Exiv2 library not found, libkexiv2 will not be compiled.])
  DO_NOT_COMPILE="libkexiv2 $DO_NOT_COMPILE"
fi

AC_LANG_SAVE
AC_LANG_CPLUSPLUS
SAVE_CPPFLAGS=$CPPFLAGS
SAVE_CXXFLAGS=$CXXFLAGS
CPPFLAGS="$CPPFLAGS $EXIV2_CFLAGS"
CXXFLAGS="$CXXFLAGS $USE_EXCEPTIONS $EXIV2_CFLAGS"
AC_CHECK_HEADER(exiv2/exiv2.hpp,
  [ AC_DEFINE(HAVE_EXIV2_HPP, 1, [Defined if you have <exiv2/exiv2.hpp> header]) ]
)
CPPFLAGS=$SAVE_CPPFLAGS
CXXFLAGS=$SAVE_CXXFLAGS
AC_LANG_RESTORE

AC_OUTPUT([ libkexiv2/libkexiv2.pc ])

# -----------------------------------------------------------------
# enable hidden visibility only if kde >= 3.3.2 and tdelibs has
# been compiled with visibility enabled
# -----------------------------------------------------------------

AC_LANG_PUSH(C++)
libkexiv2_kdemacros_cppflags=$CPPFLAGS
CPPFLAGS="$CPPFLAGS $all_includes"  
AC_MSG_CHECKING([if kdemacros.h is usable])
AC_COMPILE_IFELSE(
 [
   #include <kdemacros.h>
   #include <string>
   int other_func( void ) KDE_EXPORT;
   int other_func( void )
   { 
      std::string s("KDE_EXPORT");
      return 0;
   }
 ], 
 [ AC_MSG_RESULT([yes])
   AC_DEFINE(KDEMACROS_USABLE, 1, [kdemacros.h usable]) ], 
 [ AC_MSG_RESULT([no]) ] 
)
CPPFLAGS=$libkexiv2_kdemacros_cppflags
AC_LANG_POP(C++)