You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
rosegarden/CMakeLists.txt

122 lines
3.3 KiB

#################################################
#
# (C) 2011 Timothy Pearson
# kb9vqf (AT) pearsoncomputing.net
#
# Improvements and feedback are welcome
#
# This file is released under GPL >= 2
#
#################################################
##### set project version ########################
include( TDEVersion )
cmake_minimum_required( VERSION ${TDE_CMAKE_MINIMUM_VERSION} )
tde_set_project_version( )
##### general package setup #####################
project( rosegarden )
##### include essential cmake modules ###########
include( CheckCXXSourceCompiles )
include( CheckFunctionExists )
include( CheckIncludeFileCXX )
include( CheckLibraryExists )
include( CheckStructHasMember )
include( CheckSymbolExists )
include( CheckTypeSize )
include( FindPkgConfig )
##### set up versioning #########################
# Mark as advanced
mark_as_advanced(EXECUTABLE_OUTPUT_PATH
LIBRARY_OUTPUT_PATH
CMAKE_BACKWARDS_COMPATIBILITY)
# Rosegarden version string
set (VERSION_MAJOR "1")
set (VERSION_MINOR "7")
set (VERSION_PATCH "0")
# comment out the next line for a public release
#set (VERSION_SUFFIX "svn")
set (PACKAGE_VERSION ${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH})
if(VERSION_SUFFIX)
set (PACKAGE_VERSION "${PACKAGE_VERSION}-${VERSION_SUFFIX}")
endif(VERSION_SUFFIX)
add_definitions(-D'VERSION="${PACKAGE_VERSION}"')
##### include our cmake modules #################
include( TDEMacros )
##### setup install paths #######################
include( TDESetupPaths )
tde_setup_paths( )
##### user requested modules ####################
option( BUILD_ALL "Build all" OFF )
option( BUILD_DOC "Build doc" ${BUILD_ALL} )
option( BUILD_TRANSLATIONS "Build translations" ${BUILD_ALL} )
option( WANT_DEBUG "Include debug support" OFF )
option( WANT_FULLDBG "Full debug support (BIG executables!)" OFF )
option( WANT_SOUND "Include Sound support" ${BUILD_ALL} )
option( WANT_JACK "Include Jack (Jack Audio Connection Kit) support" ${BUILD_ALL} )
option( WANT_DSSI "Include DSSI support" ${BUILD_ALL} )
option( WANT_LIRC "Include LIRC (Linux Infrared Remote Control) support" OFF )
option( WANT_PCH "Use precompiled headers" OFF )
option( WANT_TEST "Perform unit tests" OFF )
if(WANT_TEST)
enable_testing()
endif(WANT_TEST)
if(NOT WANT_SOUND)
set(WANT_JACK OFF)
set(WANT_DSSI OFF)
add_definitions(-DNO_SOUND)
endif(NOT WANT_SOUND)
##### configure checks ##########################
include( ConfigureChecks.cmake )
###### global compiler settings #################
add_definitions(
-DHAVE_CONFIG_H
)
set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${TQT_CXX_FLAGS}" )
set( CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--no-undefined" )
set( CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--no-undefined" )
##### source directories ########################
add_subdirectory( src )
add_subdirectory( data )
tde_conditional_add_project_docs( BUILD_DOC )
tde_conditional_add_project_translations( BUILD_TRANSLATIONS )
##### write configure files #####################
configure_file( config.h.cmake config.h @ONLY )
# create and install the version file
file(WRITE "${CMAKE_BINARY_DIR}/version.txt" "${PACKAGE_VERSION}\n")
install( FILES "${CMAKE_BINARY_DIR}/version.txt" DESTINATION ${DATA_INSTALL_DIR}/rosegarden )