From cc3bceb0d70f3feafbe8d6902ba82a4062539ba1 Mon Sep 17 00:00:00 2001
From: Chris <xchrisx@uber.space>
Date: Fri, 27 Mar 2020 03:12:05 +0100
Subject: [PATCH] Live ebuilds: Add preliminary `K3b`, `K3b-i18n` and `eMoviX`
 ebuilds.

Signed-off-by: Chris <xchrisx@uber.space>
---
 media-video/emovix/Manifest                |  1 +
 media-video/emovix/emovix-0.9.0.ebuild     | 23 ++++++
 trinity-apps/k3b-i18n/k3b-i18n-9999.ebuild | 26 +++++++
 trinity-apps/k3b/k3b-9999.ebuild           | 81 ++++++++++++++++++++++
 4 files changed, 131 insertions(+)
 create mode 100644 media-video/emovix/Manifest
 create mode 100644 media-video/emovix/emovix-0.9.0.ebuild
 create mode 100644 trinity-apps/k3b-i18n/k3b-i18n-9999.ebuild
 create mode 100644 trinity-apps/k3b/k3b-9999.ebuild

diff --git a/media-video/emovix/Manifest b/media-video/emovix/Manifest
new file mode 100644
index 00000000..6592f5b2
--- /dev/null
+++ b/media-video/emovix/Manifest
@@ -0,0 +1 @@
+DIST emovix-0.9.0.tar.gz 11297252 BLAKE2B 38e077285443ab5b447a4e3e4ede52474e63003601335b5ef012d6764a9501ba28066ebf46f2de60887ae7d1485b52bd9e05b7f7bce288d67931c4077c780bb0 SHA512 87df6f124d8478d0704472adf80e541b3573bc448836f4525d99b614aba5bffbeea8f73b0b8e0b4a9a95375ee78d0f78352254eeb4f99be67611f4d17f5c3e2a
diff --git a/media-video/emovix/emovix-0.9.0.ebuild b/media-video/emovix/emovix-0.9.0.ebuild
new file mode 100644
index 00000000..fc0006e1
--- /dev/null
+++ b/media-video/emovix/emovix-0.9.0.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Copyright 2020 The Trinity Desktop Project
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+DESCRIPTION="Micro Linux distro to boot from a CD and play every video file localized in the CD root"
+HOMEPAGE="http://movix.sourceforge.net"
+SRC_URI="mirror://sourceforge/movix/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ppc ppc64 x86"
+
+RDEPEND="virtual/cdrtools"
+DEPEND="dev-lang/perl
+	virtual/awk"
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog README* TODO
+	dosym /usr/lib/win32 /usr/share/emovix/codecs
+}
diff --git a/trinity-apps/k3b-i18n/k3b-i18n-9999.ebuild b/trinity-apps/k3b-i18n/k3b-i18n-9999.ebuild
new file mode 100644
index 00000000..d1506d5a
--- /dev/null
+++ b/trinity-apps/k3b-i18n/k3b-i18n-9999.ebuild
@@ -0,0 +1,26 @@
+# Copyright 2020 The Trinity Desktop Project
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+TRINITY_MODULE_TYPE="applications"
+
+inherit trinity-base-2
+
+DESCRIPTION="K3b - internationalization translations"
+HOMEPAGE="http://trinitydesktop.org/"
+LICENSE="|| ( GPL-2 GPL-3 )"
+
+need-trinity
+
+SLOT="${TRINITY_VER}"
+
+IUSE+=" +handbook"
+
+src_configure() {
+	mycmakeargs=(
+		-DBUILD_MESSAGES=ON
+		-DBUILD_DOC="$(usex handbook)"
+	)
+
+	trinity-base-2_src_configure
+}
diff --git a/trinity-apps/k3b/k3b-9999.ebuild b/trinity-apps/k3b/k3b-9999.ebuild
new file mode 100644
index 00000000..f7aa0e79
--- /dev/null
+++ b/trinity-apps/k3b/k3b-9999.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Copyright 2020 The Trinity Desktop Project
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+TRINITY_MODULE_TYPE="applications"
+
+inherit trinity-base-2
+
+DESCRIPTION="A CD/DVD burning application for Trinity"
+HOMEPAGE="http://trinitydesktop.org/"
+LICENSE="|| ( GPL-2 GPL-3 )"
+
+need-trinity
+
+need-arts optional
+
+SLOT="${TRINITY_VER}"
+
+IUSE+=" css dvd dvdr vcd debug alsa ffmpeg ffmpeg_all_codecs \
+   flac sndfile taglib mp3 vorbis encode emovix +handbook"
+
+DEPEND+=" media-libs/libsamplerate
+	media-libs/taglib
+	media-sound/cdparanoia
+	alsa? ( media-libs/alsa-lib )
+	dvd? ( media-libs/libdvdread )
+	encode? ( media-sound/lame )
+	ffmpeg? ( virtual/ffmpeg )
+	flac? ( media-libs/flac[cxx] )
+	mp3? ( media-libs/libmad )
+	sndfile? ( media-libs/libsndfile )
+	vorbis? ( media-libs/libvorbis )"
+RDEPEND+=" ${DEPEND}
+	app-cdr/cdrdao
+	media-sound/normalize
+	virtual/cdrtools
+	dvdr? ( app-cdr/dvd+rw-tools )
+	css? ( media-libs/libdvdcss )
+	encode? ( media-sound/sox
+		media-video/transcode[dvd] )
+	emovix? ( media-video/emovix )
+	vcd? ( media-video/vcdimager )"
+
+src_configure() {
+	mycmakeargs=(
+		-DWITH_HAL=OFF
+		-DWITH_SYSTEM_LIBSAMPLERATE=ON
+		-DWITH_MUSEPACK=OFF
+		-DWITH_MUSICBRAINZ=OFF
+		-DBUILD_K3BSETUP=OFF
+		-DBUILD_DOC="$(usex handbook)"
+		-DWITH_LIBDVDREAD="$(usex dvd)"
+		-DWITH_DEBUG="$(usex debug)"
+		-DWITH_ALSA="$(usex alsa)"
+		-DWITH_FFMPEG="$(usex ffmpeg)"
+		-DWITH_FFMPEG_ALL_CODECS="$(usex ffmpeg_all_codecs)"
+		-DWITH_FLAC="$(usex flac)"
+		-DWITH_SNDFILE="$(usex sndfile)"
+		-DWITH_TAGLIB="$(usex taglib)"
+		-DWITH_MAD="$(usex mp3)"
+		-DWITH_VORBIS="$(usex vorbis)"
+		-DWITH_LAME="$(usex encode)"
+	)
+
+	trinity-base-2_src_configure
+}
+
+pkg_postinst() {
+	echo
+	elog "We don't install k3bsetup anymore because Gentoo doesn't need it."
+	elog "If you get warnings on start-up, uncheck the \"Check system"
+	elog "configuration\" option in the \"Misc\" settings window."
+	echo
+
+	local group=cdrom
+	use kernel_linux || group=operator
+	elog "Make sure you have proper read/write permissions on the cdrom device(s)."
+	elog "Usually, it is sufficient to be in the ${group} group."
+	echo
+}