# Maintainer: Michael Manley <mmanley@nasutek.com>
# Contributor: Pawel 'l0ner' Soltys <pwslts@gmail.com>
# Contributor: Calvin Morrison <mutantturkey@gmail.com>
# Contributor: David C. Rankin <drankinatty at gmail dot com>

pkgname=tde-dbus-tqt
pkgver=14.0.10
pkgrel=1
arch=('i686' 'x86_64')
url='https://scm.trinitydesktop.org/scm/git/dbus-tqt'
license=('GPL')
groups=('tde-core')
pkgdesc="Trinity TQt DBus wrapper"
depends=('tde-arts' 'dbus')
makedepends=('pkgconfig' 'cmake')
provides=('dbus-tqt')
options=('staticlibs' 'libtool' '!strip')
source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/dependencies/dbus-tqt-trinity-${pkgver}.tar.xz")
md5sums=('5a3577b3f43b3cfeb4701bb4a4e0a951')
install='trinity-dbus-tqt.install'

[ -n "$TDEDIR" ] || TDEDIR=/opt/trinity

build() {
   cd $srcdir
   msg "Creating out-of-source build directory: ${srcdir}/build"
   mkdir -p build
   cd build

   msg "Starting cmake..."
   cmake ${srcdir}/${pkgname#*-}-trinity-${pkgver}/ \
      -DCMAKE_INSTALL_PREFIX=$TDEDIR \
      -DWITH_GCC_VISIBILITY=ON

   msg "Building - $pkgname..."
   make $NUMJOBS
}

package() {
   msg "Packaging - $pkgname-$pkgver"
   cd ${srcdir}/build
   make -j1 DESTDIR="${pkgdir}" install
}