# Maintainer: Michael Manley <mmanley@nasutek.com>
# Contributor: David C. Rankin <drankinatty at gmail dot com>

pkgname=tde-avahi-tqt
pkgver=14.0.10
pkgrel=1
pkgdesc="Trinity Avahi-TQt"
arch=('i686' 'x86_64')
url='https://scm.trinitydesktop.org/scm/git/avahi-tqt'
license=('GPL')
groups=('tde-core')
depends=('tde-tqtinterface' 'avahi' 'nss-mdns')
# nss-mdns should probably move to tdelibs depends
makedepends=('pkgconfig' 'cmake')
provides=('avahi-tqt')
replaces=('trinity-avahi-tqt')
options=('staticlibs' 'libtool' '!strip')
source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/dependencies/avahi-tqt-trinity-${pkgver}.tar.xz")
md5sums=('6cce8423a3030505bb56a8c73f6235d6')

[ -n "$TDEDIR" ] || TDEDIR=/opt/trinity

build() {
   cd ${srcdir}
   msg "Creating out-of-source build directory: ${srcdir}/build"
   mkdir -p build
   cd build

   msg "Starting cmake..."
   cmake ${srcdir}/${pkgname#*-}-trinity-${pkgver}/ \
      -DCMAKE_INSTALL_PREFIX=${TDEDIR} \
      -DWITH_GCC_VISIBILITY=ON

   msg "Building - $pkgname..."
   make $NUMJOBS
}

package() {
   msg "Packaging - $pkgname"
   cd ${srcdir}/build
   make -j1 DESTDIR="$pkgdir" install
}