# Maintainer: Michael Manley <mmanley@nasutek.com>
# Contributor: Pawel 'l0ner' Soltys <pwslts@gmail.com>
# Contributor: Calvin Morrison <mutantturkey@gmail.com>
# Contributor: David C. Rankin <drankinatty at gmail dot com>
# Contributor: Slávek Banko <slavek.banko@axis.cz>

_mod=tqca
_cat=dependencies/
_kdemod="${_mod/tde/kde}"

pkgname="tde-${_mod}"
pkgver=14.0.13
pkgrel=1
pkgdesc="Trinity SSL/TLS interface for TQt Cryptographic Architecture (TQCA)"
arch=('i686' 'x86_64' 'aarch64' 'armv7h')
url="https://scm.trinitydesktop.org/scm/git/${_mod}"
license=('GPL')
groups=('tde-core')
depends=('tde-tqtinterface' 'openssl-1.0')
makedepends=('tde-cmake-trinity')
provides=(${_mod})
conflicts=("trinity-${_mod}")
replaces=("trinity-${_mod}")
options=('staticlibs' 'libtool' '!strip')
source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/${_cat}${_mod}-trinity-${pkgver}.tar.xz")
md5sums=('f6d1ec68e91cf8d4ca103628585a0466')

[ -n "$TDEDIR" ] || TDEDIR=/opt/trinity
[ -n "$QTDIR" ] || QTDIR=${TDEDIR}/tqt3

build() {
   msg "Creating out-of-source build directory: ${srcdir}/build"
   mkdir -p ${srcdir}/build
   cd ${srcdir}/build

   export PKG_CONFIG_PATH=${QTDIR}/lib/pkgconfig:${PKG_CONFIG_PATH}

   msg "Starting cmake..."
   cmake ${srcdir}/${pkgname#*-}-trinity-${pkgver}/ \
      -GNinja \
      -DCMAKE_INSTALL_PREFIX=$QTDIR \
      -DBUILD_ALL=OFF \
      -DBUILD_TQCA=ON \
      -DWITH_ALL_OPTIONS=ON

   msg "Building - $pkgname..."
   ninja $NUMJOBS
}

package() {
   msg "Packaging - $pkgname-$pkgver"
   cd ${srcdir}/build
   DESTDIR="${pkgdir}" ninja -j1 install
}