# Maintainer: Michael Manley <mmanley@nasutek.com>
# Contributor: David C. Rankin <drankinatty at gmail dot com>

pkgname=tde-tdevelop
pkgver=14.0.10
pkgrel=1
arch=('i686' 'x86_64')
url='https://scm.trinitydesktop.org/scm/git/tdevelop'
license=('GPL')
groups=('tde-devel')
pkgdesc="Trinity Desktop Developer Tools"
depends=('tde-tdelibs')
makedepends=('pkgconfig' 'cmake' 'tde-tdesdk' 'subversion')
provides=('tdevelop')
conflicts=('trinity-tdevelop' 'trinity-kdevelop')
replaces=('trinity-tdevelop')
options=('staticlibs' 'libtool' '!strip')
source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/core/tdevelop-trinity-${pkgver}.tar.xz"
        'bp000-ba5f58bf.diff')
md5sums=('ec9eb0b745d984bf77f74bdc959d5fc8'
         'e7519ea06bd63b4fc9aa7e0ac5076576')
# install=''

[ -n "$TDEDIR" ] || TDEDIR=/opt/trinity
[ -n "$QTDIR" ] || QTDIR=${TDEDIR}/tqt3

build() {
   cd ${srcdir}/${pkgname#*-}-trinity-${pkgver}
   patch -p1 < ${srcdir}/bp000-ba5f58bf.diff

   cd $srcdir
   msg "Creating out-of-source build directory: ${srcdir}/build"
   mkdir -p ${srcdir}/build
   cd ${srcdir}/build

   msg "Starting cmake..."
   cmake ${srcdir}/${pkgname#*-}-trinity-${pkgver} \
      -DCMAKE_VERBOSE_MAKEFILE=ON \
      -DCMAKE_INSTALL_PREFIX=$TDEDIR \
      -DWITH_BUILDTOOL_ALL=ON \
      -DWITH_LANGUAGE_ALL=ON \
      -DWITH_VCS_ALL=ON \
      -DBUILD_ALL=ON

   msg "Building - ${pkgname#*-}..."
   make $NUMJOBS
}

package() {
   msg "Packaging - $pkgname-$pkgver"
   cd ${srcdir}/build
   make -j1 DESTDIR="${pkgdir}" install
}