# Contributor: e1z0 <justinas at eofnet dot lt>

pkgname=tde-tdeaddons
pkgver=14.0.10
pkgrel=1
arch=('i686' 'x86_64')
url='https://scm.trinitydesktop.org/scm/git/tdeaddons'
license=('GPL')
groups=('tde-extra')
pkgdesc="Trinity Desktop Addons"
depends=('tde-tdebase')
makedepends=('pkgconfig' 'cmake' 'tde-tdegames' 'tde-tdemultimedia' 'tde-tdepim')
provides=('tdeaddons')
conflicts=('trinity-tdeaddons' 'trinity-kdeaddons')
replaces=('trinity-tdeaddons')
options=('staticlibs' 'libtool' '!strip')
source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/core/tdeaddons-trinity-${pkgver}.tar.xz")
md5sums=('27557921bf86569042c72d597b87c877')
# install=''

[ -n "$TDEDIR" ] || TDEDIR=/opt/trinity

build() {
   cd $srcdir
   msg "Creating out-of-source build directory: ${srcdir}/build"
   mkdir -p build
   cd build

   export PKG_CONFIG_PATH=${TDEDIR}/lib/pkgconfig:${PKG_CONFIG_PATH}

   msg "Starting cmake..."
   cmake ${srcdir}/${pkgname#*-}-trinity-${pkgver} \
      -DCMAKE_VERBOSE_MAKEFILE=ON \
      -DCMAKE_INSTALL_PREFIX=$TDEDIR \
      -DWITH_ARTS=ON \
      -DBUILD_ALL=ON

   msg "Building - ${pkgname#*-}..."
   make $NUMJOBS
}

package() {
   msg "Packaging - $pkgname-$pkgver"
   cd ${srcdir}/build
   make -j1 DESTDIR="${pkgdir}" install
}