# Maintainer: Michael Manley <mmanley@nasutek.com>
# Contributor: David C. Rankin <drankinatty at gmail dot com>

pkgname=tde-kmplayer
pkgver=14.0.10
pkgrel=1
pkgdesc="TDE KMPlayer"
arch=('i686' 'x86_64')
url='https://scm.trinitydesktop.org/scm/git/applications/kmplayer'
license=('GPL')
groups=('tde-extra')
depends=('tde-tdebase' 'tde-dbus-tqt' 'dbus-glib')
makedepends=('pkgconfig' 'cmake' 'mplayer' 'xine-lib' 'nspr' 'gtk2')
#provides=('kmplayer')
#conflicts=('kmplayer')
#replaces=('kmplayer')
options=('staticlibs' 'libtool' '!strip')
source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/applications/kmplayer-trinity-${pkgver}.tar.xz")
md5sums=('e817acc32c3f87cc475be8d8c7a1b4a7')
# install=''

[ -n "$TDEDIR" ] || TDEDIR=/opt/trinity

build() {
   cd $srcdir
   msg "Creating out-of-source build directory: ${srcdir}/build"
   mkdir -p build
   cd build

   export PKG_CONFIG_PATH=${TDEDIR}/lib/pkgconfig:${PKG_CONFIG_PATH}

   msg "Starting cmake..."
   cmake ${srcdir}/${pkgname#*-}-trinity-${pkgver} \
     -DCMAKE_VERBOSE_MAKEFILE=ON \
     -DCMAKE_INSTALL_PREFIX=${TDEDIR} \
     -DBUILD_ALL=ON \
     -DBUILD_KOFFICE_PLUGIN=OFF \
     -DBUILD_KGSTPLAYER=OFF

   msg "Building - ${pkgname#*-}..."
   make $NUMJOBS
}

package() {
  msg "Packaging - $pkgname-$pkgver"
  cd ${srcdir}/build
  make -j1 DESTDIR="${pkgdir}" install
}