# Maintainer: Michael Manley <mmanley@nasutek.com>
# Contributor: David C. Rankin <drankinatty at gmail dot com>

pkgname=tde-tdenetwork
pkgver=14.0.5
pkgrel=1
arch=('i686' 'x86_64')
url='http://scm.trinitydesktop.org/scm/git/tdenetwork'
license=('GPL')
groups=('tde-extra')
pkgdesc="Trinity Desktop Network Components"
depends=('tde-tdebase' 'speex' 'wireless_tools' 'wpa_supplicant')
makedepends=('pkgconfig' 'cmake')
provides=('tdenetwork')
conflicts=('trinity-tdenetwork' 'trinity-kdenetwork')
replaces=('trinity-tdenetwork')
options=('staticlibs' 'libtool' '!strip')
source=("http://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/tdenetwork-R${pkgver}.tar.bz2")
md5sums=('a8bf7062f8955179955aa6a52e58112c')
# install=''

build() {
   cd $srcdir
   msg "Creating out-of-source build directory: ${srcdir}/build"
   mkdir -p build
   cd build

   msg "Starting cmake..."
   cmake ${srcdir}/${pkgname#*-} \
      -DCMAKE_VERBOSE_MAKEFILE=ON \
      -DCMAKE_INSTALL_PREFIX=$TDEDIR \
      -DWITH_SPEEX=ON \
      -DWITH_ARTS=ON \
      -DBUILD_ALL=ON

   msg "Building - ${pkgname#*-}..."
   make $NUMJOBS
}

package() {
   msg "Packaging - $pkgname-$pkgver"
   cd ${srcdir}/build
   make -j1 DESTDIR="${pkgdir}" install
}