Conversion to the cmake building system.

Signed-off-by: gregory guy <gregory-tde@laposte.net>

CMakeLists.txt

@@ -0,0 +1,83 @@
+############################################
+#                                          #
+#  Improvements and feedbacks are welcome  #
+#                                          #
+#  This file is released under GPL >= 3    #
+#                                          #
+############################################
+
+
+cmake_minimum_required( VERSION 2.8.12 )
+
+
+#### general package setup
+
+project( sip4-tqt )
+set( VERSION R14.1.0 )
+
+
+#### include essential cmake modules
+
+include( FindPkgConfig          )
+include( CheckFunctionExists    )
+include( CheckSymbolExists      )
+include( CheckIncludeFile       )
+include( CheckLibraryExists     )
+include( CheckCSourceCompiles   )
+include( CheckCXXSourceCompiles )
+
+
+#### include our cmake modules
+
+set( CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules" )
+include( TDEMacros )
+
+
+##### setup install paths
+
+include( TDESetupPaths )
+tde_setup_paths( )
+
+
+##### optional stuff
+
+option( WITH_ALL_OPTIONS    "Enable all optional support" OFF )
+option( WITH_GCC_VISIBILITY "Enable fvisibility and fvisibility-inlines-hidden" ${WITH_ALL_OPTIONS} )
+option( WITH_THREADS        "Enable threading support"                          ON )
+
+##### user requested modules
+
+option( BUILD_ALL          "Build all" ON )
+#option( BUILD_DOC          "Build documentation" ${BUILD_ALL} )
+#option( BUILD_TRANSLATIONS "Build translations"  ${BUILD_ALL} )
+
+
+##### configure checks
+
+include( ConfigureChecks.cmake )
+
+
+###### global compiler settings 
+
+add_definitions( -DHAVE_CONFIG_H )
+
+set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${TQT_CXX_FLAGS}" )
+set( CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--no-undefined" )
+set( CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--no-undefined" )
+
+
+##### directories
+
+add_subdirectory( sipgen )
+add_subdirectory( siplib )
+
+
+##### other data ################################
+
+#tde_conditional_add_project_docs( BUILD_DOC )
+#tde_conditional_add_project_translations( BUILD_TRANSLATIONS )
+
+
+##### write configure files
+
+configure_file( config.h.cmake config.h @ONLY )

ConfigureChecks.cmake

@@ -0,0 +1,51 @@
+###########################################
+#                                         #
+#  Improvements and feedback are welcome  #
+#                                         #
+#  This file is released under GPL >= 3   #
+#                                         #
+###########################################
+
+# required stuff
+find_package( TQt )
+find_package( TDE )
+
+tde_setup_architecture_flags( )
+
+include(TestBigEndian)
+test_big_endian(WORDS_BIGENDIAN)
+
+tde_setup_largefiles( )
+
+
+##### check for gcc visibility support
+
+if( WITH_GCC_VISIBILITY )
+  tde_setup_gcc_visibility( )
+endif( WITH_GCC_VISIBILITY )
+
+
+##### look for Python
+
+find_package( PythonInterp )
+find_package( PythonLibs )
+
+if( PYTHONINTERP_FOUND AND PYTHONLIBS_FOUND )
+  message( STATUS "PYTHON_EXECUTABLE: ${PYTHON_EXECUTABLE}" )
+  message( STATUS "PYTHON_LIBRARIES: ${PYTHON_LIBRARIES}" )
+  message( STATUS "PYTHON_INCLUDE_DIRS: ${PYTHON_INCLUDE_DIRS}" )
+  execute_process (
+      COMMAND ${PYTHON_EXECUTABLE} -c "from distutils.sysconfig import get_python_lib; print get_python_lib()"
+      OUTPUT_VARIABLE PYTHON_SITE_PACKAGES
+      OUTPUT_STRIP_TRAILING_WHITESPACE
+  )
+  message( STATUS "PYTHON_SITE_PACKAGES: ${PYTHON_SITE_PACKAGES}" )
+  
+  if( WITH_THREADS )
+      find_file( WITH_THREAD pythread.h
+          PATHS ${PYTHON_INCLUDE_DIRS}
+      )
+  endif()
+ else()
+  tde_message_fatal( "The Python interpreter was not found on your system" )
+endif( PYTHONINTERP_FOUND AND PYTHONLIBS_FOUND )

config.h.cmake

@@ -0,0 +1,11 @@
+#define VERSION "@VERSION@"
+
+// Defined if you have fvisibility and fvisibility-inlines-hidden support.
+#cmakedefine __KDE_HAVE_GCC_VISIBILITY 1
+
+/* Define WORDS_BIGENDIAN to 1 if your processor stores words with the most
+   significant byte first (like Motorola and SPARC, unlike Intel). */
+#cmakedefine WORDS_BIGENDIAN @WORDS_BIGENDIAN@
+
+/* Defined if Python has threading support */
+#cmakedefine WITH_THREAD 1

sipgen/CMakeLists.txt

@@ -0,0 +1,26 @@
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${TQT_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+)
+
+##### tdesip (executable)
+
+tde_add_executable( tdesip
+
+  SOURCES
+        export.c
+        gencode.c
+        heap.c
+        lexer.c
+        main.c
+        parser.c
+        transform.c
+
+  DESTINATION ${BIN_INSTALL_DIR}
+)

siplib/CMakeLists.txt

@@ -0,0 +1,39 @@
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${TQT_INCLUDE_DIRS}
+  ${PYTHON_INCLUDE_DIRS}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+)
+
+##### tdesip (shared)
+
+tde_add_library( tdesip SHARED
+
+  SOURCES
+        siplib.c
+        apiversions.c
+        descriptors.c
+        tqtlib.c
+        threads.c
+        objmap.c
+        voidptr.c
+        bool.cpp
+  LINK
+     ${PYTHON_LIBRARIES}
+
+  DESTINATION ${PYTHON_SITE_PACKAGES}/tdesip
+)
+
+
+# headers
+
+install(
+    FILES sip.h
+    DESTINATION ${PYTHON_INCLUDE_DIRS}
+    RENAME tdesip.h
+)

siplib/sip.h

@@ -15,7 +15,9 @@
  * SIP is supplied WITHOUT ANY WARRANTY; without even the implied warranty of
  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  */
-
+#ifdef HAVE_CONFIG_H
+#include "config.h"
+#endif
 
 #ifndef _SIP_H
 #define _SIP_H