tde-packaging/arch/tde-extra/tde-tdeaccessibility/PKGBUILD

# Maintainer: David C. Rankin <drankinatty at gmail dot com>

pkgname=tde-tdeaccessibility
pkgver=14.0.10
pkgrel=1
pkgdesc="Accessibility utilities for the TDE Desktop"
arch=('i686' 'x86_64')
url="https://scm.trinitydesktop.org/scm/git/${pkgname#*-}"
license=('GPL')
groups=('tde-extra')
depends=('tde-tdelibs')
makedepends=('pkgconfig' 'cmake' 'tde-tdemultimedia')
optdepends=()
provides=("${pkgname#*-}")
conflicts=("trinity-${pkgname#*-}")
replaces=("trinity-${pkgname#*-}")
options=('staticlibs' 'libtool' '!emptydirs')
# install='pkgname.install'
source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/core/tdeaccessibility-trinity-${pkgver}.tar.xz")
md5sums=('0fb53257ee9b5dbd464a6ca8f30ef5b6')

[ -n "$TDEDIR" ] || TDEDIR=/opt/trinity

build() {
   cd $srcdir
   msg "Creating out-of-source build directory: ${srcdir}/build"
   mkdir -p build
   cd build

   export PKG_CONFIG_PATH=${TDEDIR}/lib/pkgconfig:${PKG_CONFIG_PATH}

   msg "Starting cmake..."
   cmake ${srcdir}/${pkgname#*-}-trinity-${pkgver} \
     -DCMAKE_VERBOSE_MAKEFILE=ON \
     -DCMAKE_INSTALL_PREFIX=${TDEDIR} \
     -DBUILD_ALL=ON

   msg "Building - ${pkgname#*-}..."
   make $NUMJOBS
}

package() {
  msg "Packaging - $pkgname-$pkgver"
  cd ${srcdir}/build
  make -j1 DESTDIR="${pkgdir}" install
}