app-crypt/*: move pinentry[tqt] into pinentry-tqt

Signed-off-by: Alexander Golubev <fatzer2@gmail.com>
(cherry picked from commit 01638c7e3c)

app-crypt/pinentry-tqt/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>team-gentoo@trinitydesktop.org</email>
+		<name>Trinity Gentoo ebuilds project</name>
+	</maintainer>
+	<use>
+		<flag name="ncurses">Add ncurses fallback in case tqt GUI won't be able to show a window</flag>
+	</use>
+</pkgmetadata>

app-crypt/pinentry-tqt/pinentry-tqt-1.2.1.ebuild

@@ -0,0 +1,93 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/gnupg.asc
+inherit autotools verify-sig
+
+DESCRIPTION="A tqt version of pinentry passphrase dialog"
+HOMEPAGE="https://gnupg.org/aegypten2"
+MY_PN=pinentry
+SRC_URI="mirror://gnupg/${MY_PN}/${MY_PN}-${PV}.tar.bz2"
+SRC_URI+=" verify-sig? ( mirror://gnupg/${MY_PN}/${MY_PN}-${PV}.tar.bz2.sig )"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="caps keyring ncurses"
+
+DEPEND="
+	>=dev-libs/libassuan-2.1
+	>=dev-libs/libgpg-error-1.17
+	keyring? ( app-crypt/libsecret )
+	ncurses? ( sys-libs/ncurses:= )
+	>=dev-tqt/tqt-14.1.1
+"
+RDEPEND="
+	${DEPEND}
+	app-crypt/pinentry
+"
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+	verify-sig? ( sec-keys/openpgp-keys-gnupg )
+"
+IDEPEND=">=app-eselect/eselect-pinentry-0.7.2"
+
+# DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )
+DOCS=( )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.0.0-AR.patch"
+	"${FILESDIR}/${PN}-1.2.1-automagic-capslock.patch" # bug #819939, bug #837719
+)
+
+src_prepare() {
+	default
+
+	sed "s/Q_EXPORT/TQ_EXPORT/g" -i "${S}/tqt/secqinternal_p.h" || die
+	sed "s/Q_EXPORT/TQ_EXPORT/g" -i "${S}/tqt/secqlineedit.h" || die
+	sed "s/Q_EXPORT/TQ_EXPORT/g" -i "${S}/tqt/secqstring.cpp" || die
+	sed "s/Q_EXPORT/TQ_EXPORT/g" -i "${S}/tqt/secqstring.h" || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable keyring libsecret)
+		$(use_enable ncurses fallback-curses)
+		--enable-pinentry-tqt
+		--disable-kf5-wayland
+		--disable-pinentry-{tty,efl,emacs,gnome3,curses,qt,fltk,gtk2}
+		--disable-pinentry-fltk
+		--disable-pinentry-gtk2
+		--disable-doc
+
+		$("${S}/configure" --help | grep -- '--without-.*-prefix' | sed -e 's/^ *\([^ ]*\) .*/\1/g')
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	rm "${ED}"/usr/bin/pinentry || die
+}
+
+pkg_postinst() {
+#	eselect pinentry update ifunset
+	ewarn "As for now eselect doesn't support pinentry-tqt, So in order to use it as"
+	ewarn "your default pinentry input method you will have to symlink it manually:"
+	ewarn "  ln -nsf pinentry-tqt /usr/bin/pinentry"
+	ewarn
+	ewarn "Alternatively you may add the following line to your gpg-agent.conf:"
+	ewarn "  pinentry-program /usr/bin/pinentry-tqt"
+}
+
+pkg_postrm() {
+	eselect pinentry update ifunset
+}

app-crypt/pinentry/files/pinentry-for-tqt-configure-1.2.1.patch

@@ -1,19 +0,0 @@
-diff -urN pinentry-1.2.1.orig/configure.ac pinentry-1.2.1/configure.ac
---- pinentry-1.2.1.orig/configure.ac	2023-12-27 14:38:13.605366651 +0300
-+++ pinentry-1.2.1/configure.ac	2023-12-27 14:38:53.221364994 +0300
-@@ -642,15 +642,6 @@
- 
- if test "$pinentry_tqt" != "no"; then
- 
--  if test "$pinentry_qt" = "yes"; then
--    AC_MSG_ERROR([[
--    ***
--    *** Building both Qt and TQt pinentries is not supported.
--    *** Use --disable-pinentry-qt and --disable-pinentry-qt4
--    *** if you want the TQt pinentry.
--    ***]])
--  fi
--
-   PKG_CHECK_MODULES(PINENTRY_TQT, tqt,
-                     have_tqt_libs=yes,
-                     [PKG_CHECK_MODULES(PINENTRY_TQT, tqt-mt,

app-crypt/pinentry/metadata.xml

@@ -1,8 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
-	<!-- maintainer-needed -->
-	<use>
-		<flag name="tqt">Enable support for Trinity's Qt3 fork</flag>
-	</use>
-</pkgmetadata>

app-crypt/pinentry/pinentry-1.2.1-r5.ebuild

@@ -1,115 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/gnupg.asc
-inherit autotools qmake-utils verify-sig
-
-DESCRIPTION="Simple passphrase entry dialogs which utilize the Assuan protocol"
-HOMEPAGE="https://gnupg.org/aegypten2"
-SRC_URI="mirror://gnupg/${PN}/${P}.tar.bz2"
-SRC_URI+=" verify-sig? ( mirror://gnupg/${PN}/${P}.tar.bz2.sig )"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
-IUSE="caps efl emacs gtk keyring ncurses qt5 tqt wayland X"
-
-DEPEND="
-	>=dev-libs/libassuan-2.1
-	>=dev-libs/libgcrypt-1.6.3
-	>=dev-libs/libgpg-error-1.17
-	efl? ( dev-libs/efl[X] )
-	keyring? ( app-crypt/libsecret )
-	ncurses? ( sys-libs/ncurses:= )
-	qt5? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5
-		dev-qt/qtwidgets:5
-		wayland? ( kde-plasma/kwayland:5 )
-		X? (
-			dev-qt/qtx11extras:5
-			x11-libs/libX11
-		)
-	)
-	tqt? ( dev-tqt/tqt )
-"
-RDEPEND="
-	${DEPEND}
-	gtk? ( app-crypt/gcr:0[gtk] )
-"
-BDEPEND="
-	sys-devel/gettext
-	virtual/pkgconfig
-	verify-sig? ( sec-keys/openpgp-keys-gnupg )
-"
-IDEPEND=">=app-eselect/eselect-pinentry-0.7.2"
-
-DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )
-
-PATCHES=(
-	"${FILESDIR}/${PN}-1.0.0-AR.patch"
-	"${FILESDIR}/${PN}-1.2.1-automagic-capslock.patch" # bug #819939, bug #837719
-	"${FILESDIR}/${PN}-for-tqt-configure-1.2.1.patch"
-)
-
-src_prepare() {
-	default
-
-	sed "s/Q_EXPORT/TQ_EXPORT/g" -i "${S}/tqt/secqinternal_p.h" || die
-	sed "s/Q_EXPORT/TQ_EXPORT/g" -i "${S}/tqt/secqlineedit.h" || die
-	sed "s/Q_EXPORT/TQ_EXPORT/g" -i "${S}/tqt/secqstring.cpp" || die
-	sed "s/Q_EXPORT/TQ_EXPORT/g" -i "${S}/tqt/secqstring.h" || die
-
-	unset FLTK_CONFIG
-
-	eautoreconf
-}
-
-src_configure() {
-	export PATH="$(qt5_get_bindir):${PATH}"
-	export QTLIB="$(qt5_get_libdir)"
-
-	local myeconfargs=(
-		$(use_enable efl pinentry-efl)
-		$(use_enable emacs pinentry-emacs)
-		$(use_enable keyring libsecret)
-		$(use_enable gtk pinentry-gnome3)
-		$(use_enable ncurses fallback-curses)
-		$(use_enable ncurses pinentry-curses)
-		$(use_enable qt5 pinentry-qt)
-		$(use_enable tqt pinentry-tqt)
-		$(use_enable wayland kf5-wayland)
-		$(use_enable X qtx11extras)
-		$(use_with X x)
-
-		--enable-pinentry-tty
-		--disable-pinentry-fltk
-		--disable-pinentry-gtk2
-
-		MOC="$(qt5_get_bindir)"/moc
-		GPG_ERROR_CONFIG="${ESYSROOT}"/usr/bin/${CHOST}-gpg-error-config
-		LIBASSUAN_CONFIG="${ESYSROOT}"/usr/bin/libassuan-config
-
-		$("${S}/configure" --help | grep -- '--without-.*-prefix' | sed -e 's/^ *\([^ ]*\) .*/\1/g')
-	)
-
-	econf "${myeconfargs[@]}"
-}
-
-src_install() {
-	default
-
-	rm "${ED}"/usr/bin/pinentry || die
-
-	use qt5 && dosym pinentry-qt /usr/bin/pinentry-qt5
-}
-
-pkg_postinst() {
-	eselect pinentry update ifunset
-}
-
-pkg_postrm() {
-	eselect pinentry update ifunset
-}