conversion to the cmake building system

Signed-off-by: gregory guy <g-gregory@gmx.fr>
(cherry picked from commit c582b3bf38)

CMakeLists.txt

@@ -0,0 +1,77 @@
+############################################
+#                                          #
+#  Improvements and feedbacks are welcome  #
+#                                          #
+#  This file is released under GPL >= 3    #
+#                                          #
+############################################
+
+
+cmake_minimum_required( VERSION 2.8 )
+
+
+#### general package setup
+
+project( tdeio-sword )
+set( VERSION R14.1.0 )
+
+
+#### include essential cmake modules
+
+include( FindPkgConfig          )
+include( CheckFunctionExists    )
+include( CheckIncludeFile       )
+include( CheckLibraryExists     )
+include( CheckCSourceCompiles   )
+include( CheckCXXSourceCompiles )
+
+
+#### include our cmake modules
+
+set( CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules" )
+include( TDEMacros )
+
+
+##### setup install paths
+
+include( TDESetupPaths )
+tde_setup_paths( )
+
+
+##### optional stuff
+
+option( WITH_ALL_OPTIONS "Enable all optional support" OFF                                          )
+option( WITH_GCC_VISIBILITY "Enable fvisibility and fvisibility-inlines-hidden" ${WITH_ALL_OPTIONS} )
+
+
+##### user requested modules
+
+option( BUILD_ALL "Build all" ON                             )
+option( BUILD_DOC "Build documentation" ${BUILD_ALL}         )
+option( BUILD_TRANSLATIONS "Build translations" ${BUILD_ALL} )
+
+
+##### configure checks
+
+include( ConfigureChecks.cmake )
+
+
+###### global compiler settings
+
+add_definitions( -DHAVE_CONFIG_H -UQT_NO_ASCII_CAST )
+
+set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${TQT_CXX_FLAGS}" )
+set( CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--no-undefined" )
+set( CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--no-undefined" )
+
+
+##### directories
+
+add_subdirectory( src )
+tde_conditional_add_subdirectory( BUILD_DOC doc         )
+tde_conditional_add_subdirectory( BUILD_TRANSLATIONS po ) 
+
+
+##### write configure files
+
+configure_file( config.h.cmake config.h @ONLY )

ConfigureChecks.cmake

@@ -0,0 +1,64 @@
+###########################################
+#                                         #
+#  Improvements and feedback are welcome  #
+#                                         #
+#  This file is released under GPL >= 3   #
+#                                         #
+###########################################
+
+
+# required stuff
+find_package( TQt )
+find_package( TDE )
+
+tde_setup_architecture_flags( )
+
+include(TestBigEndian)
+test_big_endian(WORDS_BIGENDIAN)
+
+
+##### check for gcc visibility support
+
+if( WITH_GCC_VISIBILITY )
+  if( NOT UNIX )
+    tde_message_fatal( "gcc visibility support was requested, but your system is not *NIX" )
+  endif( NOT UNIX )
+  set( __KDE_HAVE_GCC_VISIBILITY 1 )
+  set( CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden -fvisibility-inlines-hidden")
+  set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden -fvisibility-inlines-hidden")
+endif( WITH_GCC_VISIBILITY )
+
+
+##### gettext
+
+if( BUILD_TRANSLATIONS )
+  include( FindGettext )
+  if( GETTEXT_FOUND )
+    set( MSGFMT_EXECUTABLE ${GETTEXT_MSGFMT_EXECUTABLE} 
+      CACHE FILEPATH "path to msgfmt executable" )
+  endif( GETTEXT_FOUND )
+  
+  if( NOT MSGFMT_EXECUTABLE )
+    tde_message_fatal( "msgfmt is required but was not found on your system." )
+  endif( NOT MSGFMT_EXECUTABLE )
+endif( BUILD_TRANSLATIONS )
+
+
+##### check for sword
+
+pkg_search_module( LIBSWORD sword )
+if( NOT LIBSWORD_FOUND )
+   tde_message_fatal( "The sword library is required but was not found on your system." )
+endif( NOT LIBSWORD_FOUND )
+
+find_path( LIBSWORD_INCLUDE_DIR swbasicfilter.h
+           HINTS ${LIBSWORD_INCLUDEDIR} ${LIBSWORD_INCLUDE_DIRS}
+           PATH_SUFFIXES sword
+)
+
+find_library( LIBSWORD_LIBRARY NAMES libsword sword
+              HINTS ${LIBSWORD_LIBDIR} ${LIBSWORD_LIBRARY_DIRS}
+)
+
+set( LIBSWORD_LIBRARIES ${LIBSWORD_LIBRARY} )
+set( LIBSWORD_INCLUDE_DIRS ${LIBSWORD_INCLUDE_DIR} )

config.h.cmake

@@ -0,0 +1,8 @@
+#define VERSION "@VERSION@"
+
+// Defined if you have fvisibility and fvisibility-inlines-hidden support.
+#cmakedefine __KDE_HAVE_GCC_VISIBILITY 1
+
+/* Define WORDS_BIGENDIAN to 1 if your processor stores words with the most
+   significant byte first (like Motorola and SPARC, unlike Intel). */
+#cmakedefine WORDS_BIGENDIAN @WORDS_BIGENDIAN@

doc/CMakeLists.txt

@@ -0,0 +1 @@
+tde_auto_add_subdirectories( )

doc/en/CMakeLists.txt

@@ -0,0 +1,8 @@
+file( GLOB _html RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.html )
+
+install(
+    FILES ${_html}
+    DESTINATION ${HTML_INSTALL_DIR}/en/tdeio_sword
+)
+
+tde_create_handbook( LANG en DESTINATION tdeio_sword )

po/CMakeLists.txt

@@ -0,0 +1,5 @@
+file( GLOB _srcs RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.po )
+
+if( _srcs )
+   tde_create_translation( LANG auto OUTPUT_NAME ${PROJECT_NAME} )
+endif( )

src/CMakeLists.txt

@@ -0,0 +1,49 @@
+add_subdirectory( data )
+add_subdirectory( pics )
+
+include_directories(
+  ${CMAKE_BINARY_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${TDE_INCLUDE_DIR}
+  ${TQT_INCLUDE_DIRS}
+  ${LIBSWORD_INCLUDE_DIR}
+)
+
+link_directories(
+  ${TQT_LIBRARY_DIRS}
+  ${TDE_LIB_DIR}
+)
+
+
+##### tdeio_sword (kpart)
+
+tde_add_kpart( tdeio_sword AUTOMOC
+
+  SOURCES
+        tdeio_sword.cpp
+        renderer.cpp
+        ks_osishtml.cpp
+        ks_gbfhtml.cpp
+        ks_thmlhtml.cpp
+        utils.cpp
+        swordutils.cpp
+        swordoptions.cpp
+        filter.cpp
+        template.cpp
+        plainhtml.cpp
+  LINK
+     tdecore-shared
+     tdeio-shared
+     ${LIBSWORD_LIBRARY}
+
+  DESTINATION ${PLUGIN_INSTALL_DIR}
+)
+
+
+##### other data
+
+install(
+    FILES sword.protocol
+    DESTINATION ${SERVICES_INSTALL_DIR}
+)

src/data/CMakeLists.txt

@@ -0,0 +1,4 @@
+install(
+    FILES tdeio_sword.css swordvertical.png
+    DESTINATION ${DATA_INSTALL_DIR}/tdeio_sword
+)

src/pics/CMakeLists.txt

@@ -0,0 +1 @@
+tde_install_icons( tdeio_sword )